Gecko [ oric.aiou.edu.pk ]

Name	Size	Permission
_bootctl	2.01 KB	-rw-r--r--
_busctl	9.4 KB	-rw-r--r--
_curl	13.82 KB	-rw-r--r--
_docker	126.18 KB	-rw-r--r--
_hostnamectl	2.54 KB	-rw-r--r--
_journalctl	6.68 KB	-rw-r--r--
_kernel-install	811 B	-rw-r--r--
_localectl	3.72 KB	-rw-r--r--
_loginctl	6.1 KB	-rw-r--r--
_networkctl	1.38 KB	-rw-r--r--
_resolvectl	3.81 KB	-rw-r--r--
_sd_hosts_or_user_at_host	120 B	-rw-r--r--
_sd_outputmodes	298 B	-rw-r--r--
_sd_unit_files	255 B	-rw-r--r--
_snap	1.75 KB	-rw-r--r--
_systemctl	18.46 KB	-rw-r--r--
_systemd	3.79 KB	-rw-r--r--
_systemd-analyze	3.48 KB	-rw-r--r--
_systemd-delta	665 B	-rw-r--r--
_systemd-inhibit	1.18 KB	-rw-r--r--
_systemd-run	3.25 KB	-rw-r--r--
_systemd-tmpfiles	776 B	-rw-r--r--
_timedatectl	2.03 KB	-rw-r--r--
_udevadm	6.24 KB	-rw-r--r--

Code Editor : _timedatectl

#compdef timedatectl                    -*- shell-script -*-
# SPDX-License-Identifier: LGPL-2.1+

_timedatectl_set-timezone(){
    local -a _timezones
    _timezones=( ${(f)"$(_call_program timezones "${service}" list-timezones)"} )
    compadd "$_timezones[@]"
}

_timedatectl_set-time(){
    _message "YYYY-MM-DD HH:MM:SS"
}

_timedatectl_set-local-rtc(){
    local -a _options
    _options=(
        '0:Maintain RTC in universal time'
        '1:Maintain RTC in local time'
    )
    _describe options _options
}

_timedatectl_set-ntp(){
    local -a _options
    _options=(
        '0:Disable NTP based network time configuration'
        '1:Enable NTP based network time configuration'
    )
    _describe options _options
}

_timedatectl_command(){
    local -a _timedatectl_cmds
    _timedatectl_cmds=(
        'status:Show current time settings'
        'set-time:Set system time'
        'set-timezone:Set system timezone'
        'list-timezones:Show known timezones'
        'set-local-rtc:Control whether RTC is in local time'
        'set-ntp:Control whether NTP is enabled'
    )
    if (( CURRENT == 1 )); then
        _describe -t commands 'timedatectl command' _timedatectl_cmds
    else
        local curcontext="$curcontext"
        cmd="${${_timedatectl_cmds[(r)$words[1]:*]%%:*}}"
        if (( $#cmd )); then
            if (( $+functions[_timedatectl_$cmd] )); then
                _timedatectl_$cmd
            else
                _message "no more options"
            fi
        else
            _message "unknown timedatectl command: $words[1]"
        fi
    fi
}

_arguments -s \
    {-h,--help}'[Show this help]' \
    '--version[Show package version]' \
    '--adjust-system-clock[Adjust system clock when changing local RTC mode]' \
    '--no-pager[Do not pipe output into a pager]' \
    '--no-ask-password[Do not prompt for password]' \
    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
    {-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
    '*::timedatectl commands:_timedatectl_command'

${this.title}

Code Editor : _timedatectl