Gecko [ oric.aiou.edu.pk ]

Name	Size	Permission
README.el.cp737.txt	1.05 KB	-rw-r--r--
README.el.txt	1.05 KB	-rw-r--r--
README.txt	1.5 KB	-rw-r--r--
tutor	32.48 KB	-rw-r--r--
tutor.bar	39.94 KB	-rw-r--r--
tutor.bar.utf-8	40.86 KB	-rw-r--r--
tutor.bg.utf-8	59.11 KB	-rw-r--r--
tutor.ca	27.77 KB	-rw-r--r--
tutor.ca.utf-8	28.24 KB	-rw-r--r--
tutor.cs	25.08 KB	-rw-r--r--
tutor.cs.cp1250	25.08 KB	-rw-r--r--
tutor.cs.utf-8	27.34 KB	-rw-r--r--
tutor.da	33.87 KB	-rw-r--r--
tutor.da.utf-8	34.57 KB	-rw-r--r--
tutor.de	37.93 KB	-rw-r--r--
tutor.de.utf-8	38.33 KB	-rw-r--r--
tutor.el	29.51 KB	-rw-r--r--
tutor.el.cp737	29.51 KB	-rw-r--r--
tutor.el.utf-8	46.05 KB	-rw-r--r--
tutor.eo	34.31 KB	-rw-r--r--
tutor.eo.utf-8	34.77 KB	-rw-r--r--
tutor.es	26.95 KB	-rw-r--r--
tutor.es.utf-8	27.38 KB	-rw-r--r--
tutor.fr	37.6 KB	-rw-r--r--
tutor.fr.utf-8	38.39 KB	-rw-r--r--
tutor.hr	33.11 KB	-rw-r--r--
tutor.hr.cp1250	33.11 KB	-rw-r--r--
tutor.hr.utf-8	33.62 KB	-rw-r--r--
tutor.hu	26.56 KB	-rw-r--r--
tutor.hu.cp1250	26.56 KB	-rw-r--r--
tutor.hu.utf-8	28.28 KB	-rw-r--r--
tutor.it	35.48 KB	-rw-r--r--
tutor.it.utf-8	35.61 KB	-rw-r--r--
tutor.ja.euc	32.6 KB	-rw-r--r--
tutor.ja.sjis	32.6 KB	-rw-r--r--
tutor.ja.utf-8	43.1 KB	-rw-r--r--
tutor.ko	41.32 KB	-rw-r--r--
tutor.ko.euc	33.13 KB	-rw-r--r--
tutor.ko.utf-8	41.32 KB	-rw-r--r--
tutor.lv.utf-8	38.1 KB	-rw-r--r--
tutor.nb	33.82 KB	-rw-r--r--
tutor.nb.utf-8	34.59 KB	-rw-r--r--
tutor.nl	36.45 KB	-rw-r--r--
tutor.nl.utf-8	36.46 KB	-rw-r--r--
tutor.no	33.82 KB	-rw-r--r--
tutor.no.utf-8	34.59 KB	-rw-r--r--
tutor.pl	33.35 KB	-rw-r--r--
tutor.pl.cp1250	33.35 KB	-rw-r--r--
tutor.pl.utf-8	34.62 KB	-rw-r--r--
tutor.pt	35.42 KB	-rw-r--r--
tutor.pt.utf-8	36.12 KB	-rw-r--r--
tutor.ru	35.2 KB	-rw-r--r--
tutor.ru.cp1251	35.2 KB	-rw-r--r--
tutor.ru.utf-8	56.08 KB	-rw-r--r--
tutor.sk	32.53 KB	-rw-r--r--
tutor.sk.cp1250	32.53 KB	-rw-r--r--
tutor.sk.utf-8	34.69 KB	-rw-r--r--
tutor.sr.cp1250	32.29 KB	-rw-r--r--
tutor.sr.utf-8	32.77 KB	-rw-r--r--
tutor.sv	27.15 KB	-rw-r--r--
tutor.sv.utf-8	28.03 KB	-rw-r--r--
tutor.tr.iso9	32.79 KB	-rw-r--r--
tutor.tr.utf-8	35.35 KB	-rw-r--r--
tutor.uk.utf-8	52.31 KB	-rw-r--r--
tutor.utf-8	32.48 KB	-rw-r--r--
tutor.vi.utf-8	31.58 KB	-rw-r--r--
tutor.vim	5.33 KB	-rw-r--r--
tutor.zh.big5	23.79 KB	-rw-r--r--
tutor.zh.euc	29.34 KB	-rw-r--r--
tutor.zh.utf-8	30.67 KB	-rw-r--r--
tutor.zh_cn.utf-8	37.9 KB	-rw-r--r--
tutor.zh_tw.utf-8	30.67 KB	-rw-r--r--

Code Editor : tutor.vim

" Vim tutor support file
" Author: Eduardo F. Amatria <eferna1@platea.pntic.mec.es>
" Maintainer: Bram Moolenaar
" Last Change:	2019 Mar 30

" This Vim script is used for detecting if a translation of the
" tutor file exist, i.e., a tutor.xx file, where xx is the language.
" If the translation does not exist, or no extension is given,
" it defaults to the English version.

" It is invoked by the vimtutor shell script.

" 1. Build the extension of the file, if any:
let s:ext = ""
if strlen($xx) > 1
  let s:ext = "." . $xx
else
  let s:lang = ""
  " Check that a potential value has at least two letters.
  " Ignore "1043" and "C".
  if exists("v:lang") && v:lang =~ '\a\a'
    let s:lang = v:lang
  elseif $LC_ALL =~ '\a\a'
    let s:lang = $LC_ALL
  elseif $LC_MESSAGES =~ '\a\a' || $LC_MESSAGES ==# "C"
    " LC_MESSAGES=C can be used to explicitly ask for English messages while
    " keeping LANG non-English; don't set s:lang then.
    if $LC_MESSAGES =~ '\a\a'
      let s:lang = $LC_MESSAGES
    endif
  elseif $LANG =~ '\a\a'
    let s:lang = $LANG
  endif
  if s:lang != ""
    " Remove "@euro" (ignoring case), it may be at the end
    let s:lang = substitute(s:lang, '\c@euro', '', '')
    " On MS-Windows it may be German_Germany.1252 or Polish_Poland.1250.  How
    " about other languages?
    if s:lang =~ "German"
      let s:ext = ".de"
    elseif s:lang =~ "Polish"
      let s:ext = ".pl"
    elseif s:lang =~ "Slovak"
      let s:ext = ".sk"
    elseif s:lang =~ "Serbian"
      let s:ext = ".sr"
    elseif s:lang =~ "Czech"
      let s:ext = ".cs"
    elseif s:lang =~ "Dutch"
      let s:ext = ".nl"
    elseif s:lang =~ "Bulgarian"
      let s:ext = ".bg"
    else
      let s:ext = "." . strpart(s:lang, 0, 2)
    endif
  endif
endif

" Somehow ".ge" (Germany) is sometimes used for ".de" (Deutsch).
if s:ext =~? '\.ge'
  let s:ext = ".de"
endif

if s:ext =~? '\.en'
  let s:ext = ""
endif

" The Japanese tutor is available in three encodings, guess which one to use
" The "sjis" one is actually "cp932", it doesn't matter for this text.
if s:ext =~? '\.ja'
  if &enc =~ "euc"
    let s:ext = ".ja.euc"
  elseif &enc != "utf-8"
    let s:ext = ".ja.sjis"
  endif
endif

" The Korean tutor is available in two encodings, guess which one to use
if s:ext =~? '\.ko'
  if &enc != "utf-8"
    let s:ext = ".ko.euc"
  endif
endif

" The Chinese tutor is available in three encodings, guess which one to use
" This segment is from the above lines and modified by
" Mendel L Chan <beos@turbolinux.com.cn> for Chinese vim tutorial
" When 'encoding' is utf-8, choose between China (simplified) and Taiwan
" (traditional) based on the language, suggested by Alick Zhao.
if s:ext =~? '\.zh'
  if &enc =~ 'big5\|cp950'
    let s:ext = ".zh.big5"
  elseif &enc != 'utf-8'
    let s:ext = ".zh.euc"
  elseif s:ext =~? 'zh_tw' || (exists("s:lang") && s:lang =~? 'zh_tw')
    let s:ext = ".zh_tw"
  else
    let s:ext = ".zh_cn"
  endif
endif

" The Polish tutor is available in two encodings, guess which one to use.
if s:ext =~? '\.pl'
  if &enc =~ 1250
    let s:ext = ".pl.cp1250"
  endif
endif

" The Turkish tutor is available in two encodings, guess which one to use
if s:ext =~? '\.tr'
  if &enc == "iso-8859-9"
    let s:ext = ".tr.iso9"
  endif
endif

" The Greek tutor is available in three encodings, guess what to use.
" We used ".gr" (Greece) instead of ".el" (Greek); accept both.
if s:ext =~? '\.gr\|\.el'
  if &enc == "iso-8859-7"
    let s:ext = ".el"
  elseif &enc == "utf-8"
    let s:ext = ".el.utf-8"
  elseif &enc =~ 737
    let s:ext = ".el.cp737"
  endif
endif

" The Slovak tutor is available in three encodings, guess which one to use
if s:ext =~? '\.sk'
  if &enc =~ 1250
    let s:ext = ".sk.cp1250"
  endif
endif

" The Slovak tutor is available in two encodings, guess which one to use
" Note that the utf-8 version is the original, the cp1250 version is created
" from it.
if s:ext =~? '\.sr'
  if &enc =~ 1250
    let s:ext = ".sr.cp1250"
  endif
endif

" The Czech tutor is available in three encodings, guess which one to use
if s:ext =~? '\.cs'
  if &enc =~ 1250
    let s:ext = ".cs.cp1250"
  endif
endif

" The Russian tutor is available in three encodings, guess which one to use.
if s:ext =~? '\.ru'
  if &enc =~ '1251'
    let s:ext = '.ru.cp1251'
  elseif &enc =~ 'koi8'
    let s:ext = '.ru'
  endif
endif

" The Hungarian tutor is available in three encodings, guess which one to use.
if s:ext =~? '\.hu'
  if &enc =~ 1250
    let s:ext = ".hu.cp1250"
  elseif &enc =~ 'iso-8859-2'
    let s:ext = '.hu'
  endif
endif

" The Croatian tutor is available in three encodings, guess which one to use.
if s:ext =~? '\.hr'
  if &enc =~ 1250
    let s:ext = ".hr.cp1250"
  elseif &enc =~ 'iso-8859-2'
    let s:ext = '.hr'
  endif
endif

" If 'encoding' is utf-8 s:ext must end in utf-8.
if &enc == 'utf-8' && s:ext !~ '\.utf-8'
  let s:ext .= '.utf-8'
endif

" 2. Build the name of the file:
let s:tutorfile = "/tutor/tutor"
let s:tutorxx = $VIMRUNTIME . s:tutorfile . s:ext

" 3. Finding the file:
if filereadable(s:tutorxx)
  let $TUTOR = s:tutorxx
elseif s:ext !~ '\.utf-8' && filereadable(s:tutorxx . ".utf-8")
  " Fallback to utf-8 if available.
  let $TUTOR = s:tutorxx . ".utf-8"
else
  let $TUTOR = $VIMRUNTIME . s:tutorfile
  echo "The file " . s:tutorxx . " does not exist.\n"
  echo "Copying English version: " . $TUTOR
  4sleep
endif

" 4. Making the copy and exiting Vim:
e $TUTOR
wq! $TUTORCOPY

${this.title}

Code Editor : tutor.vim