Gecko [ oric.aiou.edu.pk ]

Name	Size	Permission
file	[ DIR ]	drwxr-xr-x
urn	[ DIR ]	drwxr-xr-x
Escape.pm	6.9 KB	-rw-r--r--
Heuristic.pm	6.37 KB	-rw-r--r--
IRI.pm	794 B	-rw-r--r--
QueryParam.pm	4.75 KB	-rw-r--r--
Split.pm	2.3 KB	-rw-r--r--
URL.pm	5.36 KB	-rw-r--r--
WithBase.pm	3.77 KB	-rw-r--r--
_foreign.pm	107 B	-rw-r--r--
_generic.pm	5.69 KB	-rw-r--r--
_idna.pm	2.03 KB	-rw-r--r--
_ldap.pm	3.17 KB	-rw-r--r--
_login.pm	231 B	-rw-r--r--
_punycode.pm	5.49 KB	-rw-r--r--
_query.pm	2.47 KB	-rw-r--r--
_segment.pm	416 B	-rw-r--r--
_server.pm	3.64 KB	-rw-r--r--
_userpass.pm	1.01 KB	-rw-r--r--
data.pm	3.31 KB	-rw-r--r--
file.pm	9.53 KB	-rw-r--r--
ftp.pm	1.03 KB	-rw-r--r--
gopher.pm	2.37 KB	-rw-r--r--
http.pm	425 B	-rw-r--r--
https.pm	144 B	-rw-r--r--
ldap.pm	2.86 KB	-rw-r--r--
ldapi.pm	441 B	-rw-r--r--
ldaps.pm	144 B	-rw-r--r--
mailto.pm	1.25 KB	-rw-r--r--
mms.pm	125 B	-rw-r--r--
news.pm	1.42 KB	-rw-r--r--
nntp.pm	127 B	-rw-r--r--
pop.pm	1.18 KB	-rw-r--r--
rlogin.pm	129 B	-rw-r--r--
rsync.pm	207 B	-rw-r--r--
rtsp.pm	125 B	-rw-r--r--
rtspu.pm	126 B	-rw-r--r--
sftp.pm	98 B	-rw-r--r--
sip.pm	1.67 KB	-rw-r--r--
sips.pm	143 B	-rw-r--r--
snews.pm	172 B	-rw-r--r--
ssh.pm	175 B	-rw-r--r--
telnet.pm	128 B	-rw-r--r--
tn3270.pm	128 B	-rw-r--r--
urn.pm	2.12 KB	-rw-r--r--

Code Editor : Split.pm

package URI::Split;

use strict;
use warnings;

our $VERSION = '1.76';

use Exporter 5.57 'import';
our @EXPORT_OK = qw(uri_split uri_join);

use URI::Escape ();

sub uri_split {
     return $_[0] =~ m,(?:([^:/?#]+):)?(?://([^/?#]*))?([^?#]*)(?:\?([^#]*))?(?:#(.*))?,;
}

sub uri_join {
    my($scheme, $auth, $path, $query, $frag) = @_;
    my $uri = defined($scheme) ? "$scheme:" : "";
    $path = "" unless defined $path;
    if (defined $auth) {
	$auth =~ s,([/?\#]), URI::Escape::escape_char($1),eg;
	$uri .= "//$auth";
	$path = "/$path" if length($path) && $path !~ m,^/,;
    }
    elsif ($path =~ m,^//,) {
	$uri .= "//";  # XXX force empty auth
    }
    unless (length $uri) {
	$path =~ s,(:), URI::Escape::escape_char($1),e while $path =~ m,^[^:/?\#]+:,;
    }
    $path =~ s,([?\#]), URI::Escape::escape_char($1),eg;
    $uri .= $path;
    if (defined $query) {
	$query =~ s,(\#), URI::Escape::escape_char($1),eg;
	$uri .= "?$query";
    }
    $uri .= "#$frag" if defined $frag;
    $uri;
}

__END__

=head1 NAME

URI::Split - Parse and compose URI strings

=head1 SYNOPSIS

use URI::Split qw(uri_split uri_join);
 ($scheme, $auth, $path, $query, $frag) = uri_split($uri);
 $uri = uri_join($scheme, $auth, $path, $query, $frag);

=head1 DESCRIPTION

Provides functions to parse and compose URI
strings.  The following functions are provided:

=over

=item ($scheme, $auth, $path, $query, $frag) = uri_split($uri)

Breaks up a URI string into its component
parts.  An C<undef> value is returned for those parts that are not
present.  The $path part is always present (but can be the empty
string) and is thus never returned as C<undef>.

No sensible value is returned if this function is called in a scalar
context.

=item $uri = uri_join($scheme, $auth, $path, $query, $frag)

Puts together a URI string from its parts.
Missing parts are signaled by passing C<undef> for the corresponding
argument.

Minimal escaping is applied to parts that contain reserved chars
that would confuse a parser.  For instance, any occurrence of '?' or '#'
in $path is always escaped, as it would otherwise be parsed back
as a query or fragment.

=back

=head1 SEE ALSO

L<URI>, L<URI::Escape>

=head1 COPYRIGHT

This library is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

=cut

${this.title}

Code Editor : Split.pm