Gecko [ oric.aiou.edu.pk ]

Name	Size	Permission
App	[ DIR ]	drwxr-xr-x
Archive	[ DIR ]	drwxr-xr-x
Attribute	[ DIR ]	drwxr-xr-x
B	[ DIR ]	drwxr-xr-x
CPAN	[ DIR ]	drwxr-xr-x
Carp	[ DIR ]	drwxr-xr-x
Class	[ DIR ]	drwxr-xr-x
Compress	[ DIR ]	drwxr-xr-x
Config	[ DIR ]	drwxr-xr-x
DBM_Filter	[ DIR ]	drwxr-xr-x
Devel	[ DIR ]	drwxr-xr-x
Digest	[ DIR ]	drwxr-xr-x
Encode	[ DIR ]	drwxr-xr-x
Exporter	[ DIR ]	drwxr-xr-x
ExtUtils	[ DIR ]	drwxr-xr-x
File	[ DIR ]	drwxr-xr-x
Filter	[ DIR ]	drwxr-xr-x
Getopt	[ DIR ]	drwxr-xr-x
HTTP	[ DIR ]	drwxr-xr-x
I18N	[ DIR ]	drwxr-xr-x
IO	[ DIR ]	drwxr-xr-x
IPC	[ DIR ]	drwxr-xr-x
JSON	[ DIR ]	drwxr-xr-x
Locale	[ DIR ]	drwxr-xr-x
Math	[ DIR ]	drwxr-xr-x
Memoize	[ DIR ]	drwxr-xr-x
Module	[ DIR ]	drwxr-xr-x
Net	[ DIR ]	drwxr-xr-x
Params	[ DIR ]	drwxr-xr-x
Parse	[ DIR ]	drwxr-xr-x
Perl	[ DIR ]	drwxr-xr-x
PerlIO	[ DIR ]	drwxr-xr-x
Pod	[ DIR ]	drwxr-xr-x
Search	[ DIR ]	drwxr-xr-x
TAP	[ DIR ]	drwxr-xr-x
Term	[ DIR ]	drwxr-xr-x
Test	[ DIR ]	drwxr-xr-x
Test2	[ DIR ]	drwxr-xr-x
Text	[ DIR ]	drwxr-xr-x
Thread	[ DIR ]	drwxr-xr-x
Tie	[ DIR ]	drwxr-xr-x
Time	[ DIR ]	drwxr-xr-x
Unicode	[ DIR ]	drwxr-xr-x
User	[ DIR ]	drwxr-xr-x
autodie	[ DIR ]	drwxr-xr-x
encoding	[ DIR ]	drwxr-xr-x
overload	[ DIR ]	drwxr-xr-x
pod	[ DIR ]	drwxr-xr-x
unicore	[ DIR ]	drwxr-xr-x
version	[ DIR ]	drwxr-xr-x
warnings	[ DIR ]	drwxr-xr-x
AnyDBM_File.pm	2.56 KB	-rw-r--r--
AutoLoader.pm	15.43 KB	-rw-r--r--
AutoSplit.pm	19.18 KB	-rw-r--r--
Benchmark.pm	30.3 KB	-rw-r--r--
CORE.pod	3.11 KB	-rw-r--r--
CPAN.pm	138.75 KB	-rw-r--r--
Carp.pm	35.12 KB	-rw-r--r--
DB.pm	18.48 KB	-rw-r--r--
DBM_Filter.pm	14.05 KB	-rw-r--r--
Digest.pm	10.45 KB	-rw-r--r--
DirHandle.pm	2.04 KB	-rw-r--r--
Dumpvalue.pm	17.14 KB	-rw-r--r--
English.pm	4.65 KB	-rw-r--r--
Env.pm	5.39 KB	-rw-r--r--
Exporter.pm	18.36 KB	-rw-r--r--
Fatal.pm	56.91 KB	-rw-r--r--
FileCache.pm	5.42 KB	-rw-r--r--
FileHandle.pm	6.63 KB	-rw-r--r--
FindBin.pm	4.45 KB	-rw-r--r--
Internals.pod	2.51 KB	-rw-r--r--
Memoize.pm	35.34 KB	-rw-r--r--
NEXT.pm	18.54 KB	-rw-r--r--
PerlIO.pm	10.21 KB	-rw-r--r--
Safe.pm	24.49 KB	-rw-r--r--
SelectSaver.pm	1.05 KB	-rw-r--r--
SelfLoader.pm	17.27 KB	-rw-r--r--
Symbol.pm	4.69 KB	-rw-r--r--
Test.pm	29.34 KB	-rw-r--r--
Test2.pm	6.24 KB	-rw-r--r--
Thread.pm	8.09 KB	-rw-r--r--
UNIVERSAL.pm	6.44 KB	-rw-r--r--
XSLoader.pm	10.99 KB	-rw-r--r--
_charnames.pm	32.39 KB	-rw-r--r--
autodie.pm	12.58 KB	-rw-r--r--
autouse.pm	4.14 KB	-rw-r--r--
base.pm	10.7 KB	-rw-r--r--
bigint.pm	22.85 KB	-rw-r--r--
bignum.pm	20.64 KB	-rw-r--r--
bigrat.pm	15.78 KB	-rw-r--r--
blib.pm	2.01 KB	-rw-r--r--
bytes.pm	3.65 KB	-rw-r--r--
bytes_heavy.pl	758 B	-rw-r--r--
charnames.pm	20.38 KB	-rw-r--r--
constant.pm	14.38 KB	-rw-r--r--
deprecate.pm	5.07 KB	-rw-r--r--
diagnostics.pm	18.59 KB	-rw-r--r--
dumpvar.pl	15.19 KB	-rw-r--r--
experimental.pm	6.9 KB	-rw-r--r--
feature.pm	17.28 KB	-rw-r--r--
fields.pm	9.25 KB	-rw-r--r--
filetest.pm	3.91 KB	-rw-r--r--
if.pm	3.53 KB	-rw-r--r--
integer.pm	3.18 KB	-rw-r--r--
less.pm	3.13 KB	-rw-r--r--
locale.pm	4.74 KB	-rw-r--r--
meta_notation.pm	2.07 KB	-rw-r--r--
ok.pm	967 B	-rw-r--r--
open.pm	7.83 KB	-rw-r--r--
overload.pm	52.04 KB	-rw-r--r--
overloading.pm	1.77 KB	-rw-r--r--
parent.pm	2.51 KB	-rw-r--r--
perl5db.pl	309.69 KB	-rw-r--r--
perlfaq.pm	77 B	-rw-r--r--
sigtrap.pm	8.53 KB	-rw-r--r--
sort.pm	3.82 KB	-rw-r--r--
strict.pm	4.63 KB	-rw-r--r--
subs.pm	901 B	-rw-r--r--
utf8.pm	10.18 KB	-rw-r--r--
utf8_heavy.pl	26.66 KB	-rw-r--r--
vars.pm	2.4 KB	-rw-r--r--
version.pm	1.93 KB	-rw-r--r--
version.pod	9.6 KB	-rw-r--r--
vmsish.pm	4.21 KB	-rw-r--r--
warnings.pm	48.82 KB	-rw-r--r--

Code Editor : Env.pm

package Env;

our $VERSION = '1.04';

=head1 NAME

Env - perl module that imports environment variables as scalars or arrays

=head1 SYNOPSIS

use Env;
    use Env qw(PATH HOME TERM);
    use Env qw($SHELL @LD_LIBRARY_PATH);

=head1 DESCRIPTION

Perl maintains environment variables in a special hash named C<%ENV>.  For
when this access method is inconvenient, the Perl module C<Env> allows
environment variables to be treated as scalar or array variables.

The C<Env::import()> function ties environment variables with suitable
names to global Perl variables with the same names.  By default it
ties all existing environment variables (C<keys %ENV>) to scalars.  If
the C<import> function receives arguments, it takes them to be a list of
variables to tie; it's okay if they don't yet exist. The scalar type
prefix '$' is inferred for any element of this list not prefixed by '$'
or '@'. Arrays are implemented in terms of C<split> and C<join>, using
C<$Config::Config{path_sep}> as the delimiter.

After an environment variable is tied, merely use it like a normal variable.
You may access its value

@path = split(/:/, $PATH);
    print join("\n", @LD_LIBRARY_PATH), "\n";

or modify it

$PATH .= ":.";
    push @LD_LIBRARY_PATH, $dir;

however you'd like. Bear in mind, however, that each access to a tied array
variable requires splitting the environment variable's string anew.

The code:

use Env qw(@PATH);
    push @PATH, '.';

is equivalent to:

use Env qw(PATH);
    $PATH .= ":.";

except that if C<$ENV{PATH}> started out empty, the second approach leaves
it with the (odd) value "C<:.>", but the first approach leaves it with "C<.>".

To remove a tied environment variable from
the environment, assign it the undefined value

undef $PATH;
    undef @LD_LIBRARY_PATH;

=head1 LIMITATIONS

On VMS systems, arrays tied to environment variables are read-only. Attempting
to change anything will cause a warning.

=head1 AUTHOR

Chip Salzenberg E<lt>F<chip@fin.uucp>E<gt>
and
Gregor N. Purdy E<lt>F<gregor@focusresearch.com>E<gt>

=cut

sub import {
    my ($callpack) = caller(0);
    my $pack = shift;
    my @vars = grep /^[\$\@]?[A-Za-z_]\w*$/, (@_ ? @_ : keys(%ENV));
    return unless @vars;

@vars = map { m/^[\$\@]/ ? $_ : '$'.$_ } @vars;

eval "package $callpack; use vars qw(" . join(' ', @vars) . ")";
    die $@ if $@;
    foreach (@vars) {
	my ($type, $name) = m/^([\$\@])(.*)$/;
	if ($type eq '$') {
	    tie ${"${callpack}::$name"}, Env, $name;
	} else {
	    if ($^O eq 'VMS') {
		tie @{"${callpack}::$name"}, Env::Array::VMS, $name;
	    } else {
		tie @{"${callpack}::$name"}, Env::Array, $name;
	    }
	}
    }
}

sub TIESCALAR {
    bless \($_[1]);
}

sub FETCH {
    my ($self) = @_;
    $ENV{$$self};
}

sub STORE {
    my ($self, $value) = @_;
    if (defined($value)) {
	$ENV{$$self} = $value;
    } else {
	delete $ENV{$$self};
    }
}

######################################################################

package Env::Array;
 
use Config;
use Tie::Array;

@ISA = qw(Tie::Array);

my $sep = $Config::Config{path_sep};

sub TIEARRAY {
    bless \($_[1]);
}

sub FETCHSIZE {
    my ($self) = @_;
    return 1 + scalar(() = $ENV{$$self} =~ /\Q$sep\E/g);
}

sub STORESIZE {
    my ($self, $size) = @_;
    my @temp = split($sep, $ENV{$$self});
    $#temp = $size - 1;
    $ENV{$$self} = join($sep, @temp);
}

sub CLEAR {
    my ($self) = @_;
    $ENV{$$self} = '';
}

sub FETCH {
    my ($self, $index) = @_;
    return (split($sep, $ENV{$$self}))[$index];
}

sub STORE {
    my ($self, $index, $value) = @_;
    my @temp = split($sep, $ENV{$$self});
    $temp[$index] = $value;
    $ENV{$$self} = join($sep, @temp);
    return $value;
}

sub EXISTS {
    my ($self, $index) = @_;
    return $index < $self->FETCHSIZE;
}

sub DELETE {
    my ($self, $index) = @_;
    my @temp = split($sep, $ENV{$$self});
    my $value = splice(@temp, $index, 1, ());
    $ENV{$$self} = join($sep, @temp);
    return $value;
}

sub PUSH {
    my $self = shift;
    my @temp = split($sep, $ENV{$$self});
    push @temp, @_;
    $ENV{$$self} = join($sep, @temp);
    return scalar(@temp);
}

sub POP {
    my ($self) = @_;
    my @temp = split($sep, $ENV{$$self});
    my $result = pop @temp;
    $ENV{$$self} = join($sep, @temp);
    return $result;
}

sub UNSHIFT {
    my $self = shift;
    my @temp = split($sep, $ENV{$$self});
    my $result = unshift @temp, @_;
    $ENV{$$self} = join($sep, @temp);
    return $result;
}

sub SHIFT {
    my ($self) = @_;
    my @temp = split($sep, $ENV{$$self});
    my $result = shift @temp;
    $ENV{$$self} = join($sep, @temp);
    return $result;
}

sub SPLICE {
    my $self = shift;
    my $offset = shift;
    my $length = shift;
    my @temp = split($sep, $ENV{$$self});
    if (wantarray) {
	my @result = splice @temp, $offset, $length, @_;
	$ENV{$$self} = join($sep, @temp);
	return @result;
    } else {
	my $result = scalar splice @temp, $offset, $length, @_;
	$ENV{$$self} = join($sep, @temp);
	return $result;
    }
}

######################################################################

package Env::Array::VMS;
use Tie::Array;

@ISA = qw(Tie::Array);
 
sub TIEARRAY {
    bless \($_[1]);
}

sub FETCHSIZE {
    my ($self) = @_;
    my $i = 0;
    while ($i < 127 and defined $ENV{$$self . ';' . $i}) { $i++; };
    return $i;
}

sub FETCH {
    my ($self, $index) = @_;
    return $ENV{$$self . ';' . $index};
}

sub EXISTS {
    my ($self, $index) = @_;
    return $index < $self->FETCHSIZE;
}

sub DELETE { }

${this.title}

Code Editor : Env.pm