Gecko [ oric.aiou.edu.pk ]

Name	Size	Permission
[	58.34 KB	-rwxr-xr-x
aa-enabled	30.52 KB	-rwxr-xr-x
aa-exec	34.52 KB	-rwxr-xr-x
addpart	30.23 KB	-rwxr-xr-x
arch	38.37 KB	-rwxr-xr-x
awk	158.74 KB	-rwxr-xr-x
b2sum	58.37 KB	-rwxr-xr-x
base32	42.34 KB	-rwxr-xr-x
base64	42.34 KB	-rwxr-xr-x
basename	38.34 KB	-rwxr-xr-x
bash	1.13 MB	-rwxr-xr-x
bashbug	6.63 KB	-rwxr-xr-x
bootctl	62.34 KB	-rwxr-xr-x
bunzip2	38.23 KB	-rwxr-xr-x
busctl	86.34 KB	-rwxr-xr-x
bzcat	38.23 KB	-rwxr-xr-x
bzcmp	2.17 KB	-rwxr-xr-x
bzdiff	2.17 KB	-rwxr-xr-x
bzegrep	3.69 KB	-rwxr-xr-x
bzexe	4.76 KB	-rwxr-xr-x
bzfgrep	3.69 KB	-rwxr-xr-x
bzgrep	3.69 KB	-rwxr-xr-x
bzip2	38.23 KB	-rwxr-xr-x
bzip2recover	18.15 KB	-rwxr-xr-x
bzless	1.27 KB	-rwxr-xr-x
bzmore	1.27 KB	-rwxr-xr-x
c_rehash	6.65 KB	-rwxr-xr-x
captoinfo	90.41 KB	-rwxr-xr-x
cat	42.4 KB	-rwxr-xr-x
catchsegv	3.25 KB	-rwxr-xr-x
cautious-launcher	853 B	-rwxr-xr-x
chage	82.53 KB	-rwxr-sr-x
chardet3	389 B	-rwxr-xr-x
chardetect3	389 B	-rwxr-xr-x
chattr	14.31 KB	-rwxr-xr-x
chcon	70.34 KB	-rwxr-xr-x
chfn	83.07 KB	-rwsr-xr-x
chgrp	70.34 KB	-rwxr-xr-x
chmod	62.37 KB	-rwxr-xr-x
choom	50.23 KB	-rwxr-xr-x
chown	70.34 KB	-rwxr-xr-x
chrt	38.23 KB	-rwxr-xr-x
chsh	51.8 KB	-rwsr-xr-x
cksum	38.34 KB	-rwxr-xr-x
clear	14.31 KB	-rwxr-xr-x
clear_console	14.23 KB	-rwxr-xr-x
cloud-id	396 B	-rwxr-xr-x
cloud-init	400 B	-rwxr-xr-x
cloud-init-per	2.06 KB	-rwxr-xr-x
cmp	50.09 KB	-rwxr-xr-x
comm	42.37 KB	-rwxr-xr-x
compose	18.05 KB	-rwxr-xr-x
console-conf	406 B	-rwxr-xr-x
core-sshd-host-keygen	1.49 KB	-rwxr-xr-x
cp	150.37 KB	-rwxr-xr-x
csplit	54.37 KB	-rwxr-xr-x
ctstat	30.51 KB	-rwxr-xr-x
cut	46.37 KB	-rwxr-xr-x
cvtsudoers	266.7 KB	-rwxr-xr-x
dash	126.77 KB	-rwxr-xr-x
date	106.37 KB	-rwxr-xr-x
dbus-cleanup-sockets	14.14 KB	-rwxr-xr-x
dbus-daemon	243.2 KB	-rwxr-xr-x
dbus-monitor	30.14 KB	-rwxr-xr-x
dbus-run-session	14.14 KB	-rwxr-xr-x
dbus-send	30.14 KB	-rwxr-xr-x
dbus-update-activation-environ...	14.14 KB	-rwxr-xr-x
dbus-uuidgen	14.14 KB	-rwxr-xr-x
dd	78.38 KB	-rwxr-xr-x
deb-systemd-helper	20.83 KB	-rwxr-xr-x
deb-systemd-invoke	4.33 KB	-rwxr-xr-x
delpart	30.23 KB	-rwxr-xr-x
df	90.95 KB	-rwxr-xr-x
dh_bash-completion	2.39 KB	-rwxr-xr-x
diff	214.34 KB	-rwxr-xr-x
diff3	66.21 KB	-rwxr-xr-x
dir	138.81 KB	-rwxr-xr-x
dircolors	46.34 KB	-rwxr-xr-x
dirname	38.34 KB	-rwxr-xr-x
dmesg	82.46 KB	-rwxr-xr-x
dnsdomainname	26.23 KB	-rwxr-xr-x
domainname	26.23 KB	-rwxr-xr-x
dpkg-deb	174.54 KB	-rwxr-xr-x
du	106.37 KB	-rwxr-xr-x
ec2metadata	7.12 KB	-rwxr-xr-x
echo	38.34 KB	-rwxr-xr-x
edit	18.05 KB	-rwxr-xr-x
editor	1.29 MB	-rwxr-xr-x
egrep	28 B	-rwxr-xr-x
env	42.34 KB	-rwxr-xr-x
ex	1.29 MB	-rwxr-xr-x
expand	42.37 KB	-rwxr-xr-x
expiry	30.58 KB	-rwxr-sr-x
expr	54.34 KB	-rwxr-xr-x
factor	78.37 KB	-rwxr-xr-x
faillog	22.59 KB	-rwxr-xr-x
fallocate	34.23 KB	-rwxr-xr-x
false	38.34 KB	-rwxr-xr-x
fgrep	28 B	-rwxr-xr-x
file	26.47 KB	-rwxr-xr-x
finalrd	2.1 KB	-rwxr-xr-x
fincore	34.27 KB	-rwxr-xr-x
find	312.66 KB	-rwxr-xr-x
findmnt	71.41 KB	-rwxr-xr-x
flock	34.3 KB	-rwxr-xr-x
fmt	46.34 KB	-rwxr-xr-x
fold	42.34 KB	-rwxr-xr-x
free	26.23 KB	-rwxr-xr-x
gdbserver	509.55 KB	-rwxr-xr-x
getconf	34.29 KB	-rwxr-xr-x
getent	38.65 KB	-rwxr-xr-x
getopt	22.23 KB	-rwxr-xr-x
gpasswd	86.39 KB	-rwsr-xr-x
gpgv	447.15 KB	-rwxr-xr-x
grep	194.47 KB	-rwxr-xr-x
groups	38.34 KB	-rwxr-xr-x
growpart	23.95 KB	-rwxr-xr-x
gunzip	2.29 KB	-rwxr-xr-x
gzexe	6.3 KB	-rwxr-xr-x
gzip	95.21 KB	-rwxr-xr-x
head	46.37 KB	-rwxr-xr-x
helpztags	2.46 KB	-rwxr-xr-x
hostid	38.34 KB	-rwxr-xr-x
hostname	26.23 KB	-rwxr-xr-x
hostnamectl	26.22 KB	-rwxr-xr-x
i386	26.5 KB	-rwxr-xr-x
iconv	66.41 KB	-rwxr-xr-x
id	46.37 KB	-rwxr-xr-x
infocmp	62.38 KB	-rwxr-xr-x
infotocap	90.41 KB	-rwxr-xr-x
install	154.41 KB	-rwxr-xr-x
ionice	30.23 KB	-rwxr-xr-x
ip	597.62 KB	-rwxr-xr-x
ipcmk	34.3 KB	-rwxr-xr-x
ipcrm	34.23 KB	-rwxr-xr-x
ipcs	66.23 KB	-rwxr-xr-x
iptables-xml	96.97 KB	-rwxr-xr-x
ischroot	14.2 KB	-rwxr-xr-x
join	54.37 KB	-rwxr-xr-x
journalctl	78.24 KB	-rwxr-xr-x
jsondiff	1004 B	-rwxr-xr-x
jsonpatch	3.58 KB	-rwxr-xr-x
jsonpatch-jsondiff	1004 B	-rwxr-xr-x
jsonpointer	1.79 KB	-rwxr-xr-x
jsonschema	397 B	-rwxr-xr-x
kernel-install	5.07 KB	-rwxr-xr-x
kill	30.23 KB	-rwxr-xr-x
kmod	170.34 KB	-rwxr-xr-x
kmodsign	22.29 KB	-rwxr-xr-x
last	50.23 KB	-rwxr-xr-x
lastb	50.23 KB	-rwxr-xr-x
lastlog	31.66 KB	-rwxr-xr-x
lcf	7.6 KB	-rwxr-xr-x
ldd	5.3 KB	-rwxr-xr-x
less	175.84 KB	-rwxr-xr-x
lessecho	14.31 KB	-rwxr-xr-x
lessfile	8.36 KB	-rwxr-xr-x
lesskey	23.72 KB	-rwxr-xr-x
lesspipe	8.36 KB	-rwxr-xr-x
link	38.34 KB	-rwxr-xr-x
linux32	26.5 KB	-rwxr-xr-x
linux64	26.5 KB	-rwxr-xr-x
ln	74.38 KB	-rwxr-xr-x
lnstat	30.51 KB	-rwxr-xr-x
locale	57.56 KB	-rwxr-xr-x
locale-check	14.16 KB	-rwxr-xr-x
localectl	26.22 KB	-rwxr-xr-x
localedef	326.96 KB	-rwxr-xr-x
logger	50.82 KB	-rwxr-xr-x
login	55.77 KB	-rwxr-xr-x
loginctl	58.34 KB	-rwxr-xr-x
logname	38.34 KB	-rwxr-xr-x
ls	138.81 KB	-rwxr-xr-x
lsattr	14.31 KB	-rwxr-xr-x
lsblk	130.23 KB	-rwxr-xr-x
lscpu	98.23 KB	-rwxr-xr-x
lsipc	94.23 KB	-rwxr-xr-x
lslocks	38.55 KB	-rwxr-xr-x
lslogins	66.23 KB	-rwxr-xr-x
lsmem	66.23 KB	-rwxr-xr-x
lsmod	170.34 KB	-rwxr-xr-x
lsns	50.23 KB	-rwxr-xr-x
man	128 B	-rwxr-xr-x
mawk	158.74 KB	-rwxr-xr-x
mcookie	34.3 KB	-rwxr-xr-x
md5sum	46.37 KB	-rwxr-xr-x
md5sum.textutils	46.37 KB	-rwxr-xr-x
mesg	14.23 KB	-rwxr-xr-x
miniterm	34.28 KB	-rwxr-xr-x
mkdir	86.34 KB	-rwxr-xr-x
mkfifo	66.34 KB	-rwxr-xr-x
mknod	70.34 KB	-rwxr-xr-x
mksquashfs	205.96 KB	-rwxr-xr-x
mkswapfile	865 B	-rwxr-xr-x
mktemp	46.34 KB	-rwxr-xr-x
more	42.15 KB	-rwxr-xr-x
mount	54.23 KB	-rwsr-xr-x
mountpoint	14.23 KB	-rwxr-xr-x
mv	146.38 KB	-rwxr-xr-x
namei	34.23 KB	-rwxr-xr-x
nawk	158.74 KB	-rwxr-xr-x
nc	42.64 KB	-rwxr-xr-x
nc.openbsd	42.64 KB	-rwxr-xr-x
netcat	42.64 KB	-rwxr-xr-x
networkctl	74.23 KB	-rwxr-xr-x
newgrp	43.73 KB	-rwsr-xr-x
nice	42.34 KB	-rwxr-xr-x
nisdomainname	26.23 KB	-rwxr-xr-x
nl	42.43 KB	-rwxr-xr-x
nohup	42.34 KB	-rwxr-xr-x
nproc	42.34 KB	-rwxr-xr-x
nsenter	34.43 KB	-rwxr-xr-x
nstat	78.23 KB	-rwxr-xr-x
numfmt	66.4 KB	-rwxr-xr-x
od	70.37 KB	-rwxr-xr-x
openssl	735.68 KB	-rwxr-xr-x
p11-kit	34.39 KB	-rwxr-xr-x
p11tool	355.38 KB	-rwxr-xr-x
pager	175.84 KB	-rwxr-xr-x
partx	118.23 KB	-rwxr-xr-x
passwd	66.61 KB	-rwsr-xr-x
paste	42.37 KB	-rwxr-xr-x
pathchk	38.34 KB	-rwxr-xr-x
pdb3	61.27 KB	-rwxr-xr-x
pdb3.8	61.27 KB	-rwxr-xr-x
perl	3.32 MB	-rwxr-xr-x
perl5.30.0	3.32 MB	-rwxr-xr-x
pgrep	30.24 KB	-rwxr-xr-x
pidof	26.38 KB	-rwxr-xr-x
ping	71.07 KB	-rwxr-xr-x
ping4	71.07 KB	-rwxr-xr-x
ping6	71.07 KB	-rwxr-xr-x
pinky	42.37 KB	-rwxr-xr-x
pkcs11-tool	152.77 KB	-rwxr-xr-x
pkill	30.24 KB	-rwxr-xr-x
pldd	22.37 KB	-rwxr-xr-x
pmap	34.24 KB	-rwxr-xr-x
pr	74.43 KB	-rwxr-xr-x
print	18.05 KB	-rwxr-xr-x
printenv	38.34 KB	-rwxr-xr-x
printf	58.34 KB	-rwxr-xr-x
prlimit	38.74 KB	-rwxr-xr-x
ps	134.46 KB	-rwxr-xr-x
ptx	78.4 KB	-rwxr-xr-x
pwd	42.34 KB	-rwxr-xr-x
pwdx	14.23 KB	-rwxr-xr-x
py3clean	7.63 KB	-rwxr-xr-x
py3compile	11.84 KB	-rwxr-xr-x
py3versions	11.44 KB	-rwxr-xr-x
pydoc3	79 B	-rwxr-xr-x
pydoc3.8	79 B	-rwxr-xr-x
pygettext3	21.03 KB	-rwxr-xr-x
pygettext3.8	21.03 KB	-rwxr-xr-x
pyjwt3	372 B	-rwxr-xr-x
python3	5.21 MB	-rwxr-xr-x
python3.8	5.21 MB	-rwxr-xr-x
rbash	1.13 MB	-rwxr-xr-x
rcp	114.3 KB	-rwxr-xr-x
rdma	130.23 KB	-rwxr-xr-x
readlink	50.34 KB	-rwxr-xr-x
realpath	50.37 KB	-rwxr-xr-x
rename.ul	22.23 KB	-rwxr-xr-x
renice	14.23 KB	-rwxr-xr-x
reset	30.31 KB	-rwxr-xr-x
resizepart	62.23 KB	-rwxr-xr-x
resolvectl	126.38 KB	-rwxr-xr-x
rev	14.23 KB	-rwxr-xr-x
rgrep	30 B	-rwxr-xr-x
rlogin	774.95 KB	-rwxr-xr-x
rm	70.37 KB	-rwxr-xr-x
rmdir	46.34 KB	-rwxr-xr-x
routef	208 B	-rwxr-xr-x
routel	1.62 KB	-rwxr-xr-x
rsh	774.95 KB	-rwxr-xr-x
rtstat	30.51 KB	-rwxr-xr-x
run-mailcap	18.05 KB	-rwxr-xr-x
run-parts	26.51 KB	-rwxr-xr-x
runcon	38.34 KB	-rwxr-xr-x
rview	1.29 MB	-rwxr-xr-x
savelog	10.24 KB	-rwxr-xr-x
sbattach	58.48 KB	-rwxr-xr-x
sbkeysync	66.7 KB	-rwxr-xr-x
sbsiglist	58.55 KB	-rwxr-xr-x
sbsign	58.55 KB	-rwxr-xr-x
sbvarsign	66.61 KB	-rwxr-xr-x
sbverify	62.48 KB	-rwxr-xr-x
scp	114.3 KB	-rwxr-xr-x
script	54.23 KB	-rwxr-xr-x
scriptreplay	30.23 KB	-rwxr-xr-x
sdiff	50.09 KB	-rwxr-xr-x
sed	118.45 KB	-rwxr-xr-x
see	18.05 KB	-rwxr-xr-x
select-editor	2.38 KB	-rwxr-xr-x
sensible-browser	1.2 KB	-rwxr-xr-x
sensible-editor	1.14 KB	-rwxr-xr-x
sensible-pager	452 B	-rwxr-xr-x
seq	50.34 KB	-rwxr-xr-x
setarch	26.5 KB	-rwxr-xr-x
setpriv	46.23 KB	-rwxr-xr-x
setsid	14.23 KB	-rwxr-xr-x
setterm	46.23 KB	-rwxr-xr-x
sftp	166.51 KB	-rwxr-xr-x
sg	43.73 KB	-rwsr-xr-x
sh	126.77 KB	-rwxr-xr-x
sha1sum	50.37 KB	-rwxr-xr-x
sha224sum	58.37 KB	-rwxr-xr-x
sha256sum	58.37 KB	-rwxr-xr-x
sha384sum	66.37 KB	-rwxr-xr-x
sha512sum	66.37 KB	-rwxr-xr-x
shred	62.37 KB	-rwxr-xr-x
shuf	58.34 KB	-rwxr-xr-x
skill	30.23 KB	-rwxr-xr-x
slabtop	22.23 KB	-rwxr-xr-x
sleep	38.34 KB	-rwxr-xr-x
slogin	774.95 KB	-rwxr-xr-x
snap	16.86 MB	-rwxr-xr-x
snice	30.23 KB	-rwxr-xr-x
sort	114.63 KB	-rwxr-xr-x
split	58.77 KB	-rwxr-xr-x
ss	164.84 KB	-rwxr-xr-x
ssh	774.95 KB	-rwxr-xr-x
ssh-add	362.28 KB	-rwxr-xr-x
ssh-agent	342.29 KB	-rwxr-sr-x
ssh-argv0	1.42 KB	-rwxr-xr-x
ssh-copy-id	10.41 KB	-rwxr-xr-x
ssh-keygen	466.3 KB	-rwxr-xr-x
ssh-keyscan	454.3 KB	-rwxr-xr-x
stat	86.37 KB	-rwxr-xr-x
stdbuf	50.34 KB	-rwxr-xr-x
stty	82.37 KB	-rwxr-xr-x
su	66.23 KB	-rwsr-xr-x
sudo	162.16 KB	-rwsr-xr-x
sudoedit	162.16 KB	-rwsr-xr-x
sudoreplay	63 KB	-rwxr-xr-x
sum	46.34 KB	-rwxr-xr-x
sync	38.34 KB	-rwxr-xr-x
systemctl	973.23 KB	-rwxr-xr-x
systemd	1.55 MB	-rwxr-xr-x
systemd-analyze	1.51 MB	-rwxr-xr-x
systemd-ask-password	14.34 KB	-rwxr-xr-x
systemd-cat	18.23 KB	-rwxr-xr-x
systemd-cgls	22.33 KB	-rwxr-xr-x
systemd-cgtop	38.24 KB	-rwxr-xr-x
systemd-delta	26.22 KB	-rwxr-xr-x
systemd-detect-virt	18.22 KB	-rwxr-xr-x
systemd-escape	22.22 KB	-rwxr-xr-x
systemd-hwdb	106.52 KB	-rwxr-xr-x
systemd-id128	22.22 KB	-rwxr-xr-x
systemd-inhibit	22.24 KB	-rwxr-xr-x
systemd-machine-id-setup	26.32 KB	-rwxr-xr-x
systemd-mount	50.45 KB	-rwxr-xr-x
systemd-notify	18.23 KB	-rwxr-xr-x
systemd-path	18.22 KB	-rwxr-xr-x
systemd-resolve	126.38 KB	-rwxr-xr-x
systemd-run	58.42 KB	-rwxr-xr-x
systemd-socket-activate	26.22 KB	-rwxr-xr-x
systemd-stdio-bridge	22.23 KB	-rwxr-xr-x
systemd-sysusers	54.52 KB	-rwxr-xr-x
systemd-tmpfiles	86.41 KB	-rwxr-xr-x
systemd-tty-ask-password-agent	30.22 KB	-rwxr-xr-x
systemd-umount	50.45 KB	-rwxr-xr-x
tabs	18.3 KB	-rwxr-xr-x
tac	42.34 KB	-rwxr-xr-x
tail	70.4 KB	-rwxr-xr-x
tar	437.61 KB	-rwxr-xr-x
taskset	34.23 KB	-rwxr-xr-x
tee	42.37 KB	-rwxr-xr-x
tempfile	14.02 KB	-rwxr-xr-x
test	54.34 KB	-rwxr-xr-x
tic	90.41 KB	-rwxr-xr-x
timedatectl	815 B	-rwxr-xr-x
timedatectl.real	46.22 KB	-rwxr-xr-x
timeout	42.77 KB	-rwxr-xr-x
tload	22.24 KB	-rwxr-xr-x
toe	22.3 KB	-rwxr-xr-x
top	126.05 KB	-rwxr-xr-x
touch	98.37 KB	-rwxr-xr-x
tput	26.34 KB	-rwxr-xr-x
tr	50.34 KB	-rwxr-xr-x
true	38.34 KB	-rwxr-xr-x
truncate	42.34 KB	-rwxr-xr-x
tset	30.31 KB	-rwxr-xr-x
tsort	42.34 KB	-rwxr-xr-x
tty	38.34 KB	-rwxr-xr-x
tzselect	15.02 KB	-rwxr-xr-x
ucf	39.73 KB	-rwxr-xr-x
ucfq	18.91 KB	-rwxr-xr-x
ucfr	10.47 KB	-rwxr-xr-x
udevadm	931.2 KB	-rwxr-xr-x
umount	38.23 KB	-rwsr-xr-x
uname	38.37 KB	-rwxr-xr-x
uncompress	2.29 KB	-rwxr-xr-x
unexpand	42.37 KB	-rwxr-xr-x
uniq	50.37 KB	-rwxr-xr-x
unlink	38.34 KB	-rwxr-xr-x
unshare	42.43 KB	-rwxr-xr-x
unsquashfs	112.12 KB	-rwxr-xr-x
update-alternatives	54.41 KB	-rwxr-xr-x
uptime	14.23 KB	-rwxr-xr-x
users	38.34 KB	-rwxr-xr-x
utmpdump	30.23 KB	-rwxr-xr-x
vcs-run	6.75 KB	-rwxr-xr-x
vdir	138.81 KB	-rwxr-xr-x
vi	1.29 MB	-rwxr-xr-x
view	1.29 MB	-rwxr-xr-x
vim.tiny	1.29 MB	-rwxr-xr-x
vmstat	38.25 KB	-rwxr-xr-x
w	22.23 KB	-rwxr-xr-x
w.procps	22.23 KB	-rwxr-xr-x
wall	34.23 KB	-rwxr-xr-x
watch	26.57 KB	-rwxr-xr-x
wc	46.34 KB	-rwxr-xr-x
wdctl	34.23 KB	-rwxr-xr-x
whereis	34.66 KB	-rwxr-xr-x
which	946 B	-rwxr-xr-x
who	58.37 KB	-rwxr-xr-x
whoami	38.34 KB	-rwxr-xr-x
wpa_passphrase	78.32 KB	-rwxr-xr-x
x86_64	26.5 KB	-rwxr-xr-x
xargs	74.37 KB	-rwxr-xr-x
xdg-open	38 B	-rwxr-xr-x
xdg-settings	1.68 KB	-rwxr-xr-x
xxd	18.27 KB	-rwxr-xr-x
yes	38.34 KB	-rwxr-xr-x
ypdomainname	26.23 KB	-rwxr-xr-x
zcat	1.94 KB	-rwxr-xr-x
zcmp	1.64 KB	-rwxr-xr-x
zdiff	5.76 KB	-rwxr-xr-x
zdump	26.21 KB	-rwxr-xr-x
zegrep	29 B	-rwxr-xr-x
zfgrep	29 B	-rwxr-xr-x
zforce	2.03 KB	-rwxr-xr-x
zgrep	7.91 KB	-rwxr-xr-x
zless	2.15 KB	-rwxr-xr-x
zmore	1.8 KB	-rwxr-xr-x
znew	4.47 KB	-rwxr-xr-x

Code Editor : deb-systemd-helper

#!/usr/bin/perl
# vim:ts=4:sw=4:expandtab
# © 2013-2014 Michael Stapelberg <stapelberg@debian.org>
#
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions are met:
#
#     * Redistributions of source code must retain the above copyright
#       notice, this list of conditions and the following disclaimer.
#
#     * Redistributions in binary form must reproduce the above copyright
#       notice, this list of conditions and the following disclaimer in the
#       documentation and/or other materials provided with the distribution.
#
#     * Neither the name of Michael Stapelberg nor the
#       names of contributors may be used to endorse or promote products
#       derived from this software without specific prior written permission.
# .
# THIS SOFTWARE IS PROVIDED BY Michael Stapelberg ''AS IS'' AND ANY
# EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
# WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
# DISCLAIMED. IN NO EVENT SHALL Michael Stapelberg BE LIABLE FOR ANY
# DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
# (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
# LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
# ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
# SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

=head1 NAME

deb-systemd-helper - subset of systemctl for machines not running systemd

=head1 SYNOPSIS

=head1 DESCRIPTION

B<deb-systemd-helper> is a Debian-specific helper script which re-implements
the enable, disable, is-enabled and reenable commands from systemctl.

The "enable" action will only be performed once (when first installing the
package). On the first "enable", a state file is created which will be deleted
upon "purge".

The "mask" action will keep state on whether the service was enabled/disabled
before and will properly return to that state on "unmask".

The "was-enabled" action is not present in systemctl, but is required in Debian
so that we can figure out whether a service was enabled before we installed an
updated service file. See http://bugs.debian.org/717603 for details.

The "debian-installed" action is also not present in systemctl. It returns 0 if
the state file of at least one of the given units is present.

The "update-state" action is also not present in systemctl. It updates
B<deb-systemd-helper>'s state file, removing obsolete entries (e.g. service
files that are no longer shipped by the package) and adding new entries (e.g.
new service files shipped by the package) without enabling them.

B<deb-systemd-helper> is intended to be used from maintscripts to enable
systemd unit files. It is specifically NOT intended to be used interactively by
users. Instead, users should run systemd and use systemctl, or not bother about
the systemd enabled state in case they are not running systemd.

=head1 ENVIRONMENT

=over 4

=item B<_DEB_SYSTEMD_HELPER_DEBUG>

If you export _DEB_SYSTEMD_HELPER_DEBUG=1, deb-systemd-helper will print debug
messages to stderr (thus visible in dpkg runs). Please include these when
filing a bugreport.

=back

=cut

use strict;
use warnings;
use File::Path qw(make_path); # in core since Perl 5.001
use File::Basename; # in core since Perl 5
use File::Temp qw(tempfile); # in core since Perl 5.6.1
use Getopt::Long; # in core since Perl 5
# Make Data::Dumper::Dumper available if present (not present on systems that
# only have perl-base, not perl).
eval { require Data::Dumper; } or *Data::Dumper::Dumper = sub { "no Data::Dumper" };

use constant {
     SYSTEM_INSTANCE_ENABLED_STATE_DIR => '/var/lib/systemd/deb-systemd-helper-enabled',
     USER_INSTANCE_ENABLED_STATE_DIR   => '/var/lib/systemd/deb-systemd-user-helper-enabled',
     SYSTEM_INSTANCE_MASKED_STATE_DIR  => '/var/lib/systemd/deb-systemd-helper-masked',
     USER_INSTANCE_MASKED_STATE_DIR    => '/var/lib/systemd/deb-systemd-user-helper-masked',
};

my $quiet = 0;
my $instance = 'system';
my $enabled_state_dir = SYSTEM_INSTANCE_ENABLED_STATE_DIR;
my $masked_state_dir = SYSTEM_INSTANCE_MASKED_STATE_DIR;

# Globals are bad, but in this specific case, it really makes things much
# easier to write and understand.
my $changed_sth;
my $has_systemctl = -x "/bin/systemctl";

sub error {
    print STDERR "$0: error: @_\n";
    exit (1);
}

sub debug {
    my ($msg) = @_;
    return if !defined($ENV{_DEB_SYSTEMD_HELPER_DEBUG}) || $ENV{_DEB_SYSTEMD_HELPER_DEBUG} != 1;
    print STDERR "(deb-systemd-helper DEBUG) $msg\n";
}

sub is_purge {
    return (defined($ENV{_DEB_SYSTEMD_HELPER_PURGE}) && $ENV{_DEB_SYSTEMD_HELPER_PURGE} == 1)
}

sub find_unit {
    my ($scriptname) = @_;

my $service_path = $scriptname;

if (-f "/etc/systemd/$instance/$scriptname") {
        $service_path = "/etc/systemd/$instance/$scriptname";
    } elsif (-f "/lib/systemd/$instance/$scriptname") {
        $service_path = "/lib/systemd/$instance/$scriptname";
    } elsif (-f "/usr/lib/systemd/$instance/$scriptname") {
        $service_path = "/usr/lib/systemd/$instance/$scriptname";
    }

return $service_path;
}

sub dsh_state_path {
    my ($scriptname) = @_;
    return $enabled_state_dir . '/' . basename($scriptname) . '.dsh-also';
}

sub state_file_entries {
    my ($dsh_state) = @_;
    debug "Reading state file $dsh_state";
    my @entries;
    if (open(my $fh, '<', $dsh_state)) {
        @entries = map { chomp; $_ } <$fh>;
        close($fh);
    }
    return @entries;
}

# Writes $service_link into $dsh_state unless it’s already in there.
sub record_in_statefile {
    my ($dsh_state, $service_link) = @_;

# Appending a newline makes the following code simpler; we can skip
    # chomp()ing and appending newlines in every print.
    $service_link .= "\n";

make_path(dirname($dsh_state));
    my $line_exists;
    my ($outfh, $tmpname) = tempfile('.stateXXXXX',
        DIR => dirname($dsh_state),
        SUFFIX => '.tmp',
        UNLINK => 0);
    chmod(0644, $tmpname);
    if (-e $dsh_state) {
        open(my $infh, '<', $dsh_state) or error("unable to read from $dsh_state");
        while (<$infh>) {
            $line_exists = 1 if $_ eq $service_link;
            print $outfh $_;
        }
        close($infh);
    }
    print $outfh $service_link unless $line_exists;
    close($outfh);

debug "Renaming temp file $tmpname to state file $dsh_state";
    rename($tmpname, $dsh_state) or
        error("Unable to move $tmpname to $dsh_state");
}

# Gets the transitive closure of links, i.e. all links that need to be created
# when enabling this service file. Not straight-forward because service files
# can refer to other service files using Also=.
sub get_link_closure {
    my ($scriptname, $service_path) = @_;

my @links;

my $unit_name = basename($service_path);

# The keys parsed from the unit file below can only have unit names
    # as values. Since unit names can't have whitespace in systemd,
    # simply use split and strip any leading/trailing quotes. See
    # systemd-escape(1) for examples of valid unit names.
    open my $fh, '<', $service_path or error("unable to read $service_path");
    while (my $line = <$fh>) {
        chomp($line);
        my $service_link;

if ($line =~ /^\s*(WantedBy|RequiredBy)=(.+)$/i) {
            for my $value (split(/\s+/, $2)) {
                $value =~ s/^(["'])(.*)\g1$/$2/;
                my $wants_dir = "/etc/systemd/$instance/$value";
                $wants_dir .= '.wants' if $1 eq 'WantedBy';
                $wants_dir .= '.requires' if $1 eq 'RequiredBy';
                push @links, { dest => $service_path, src => "$wants_dir/$scriptname" };
            }
        }

if ($line =~ /^\s*Also=(.+)$/i) {
            for my $value (split(/\s+/, $1)) {
                $value =~ s/^(["'])(.*)\g1$/$2/;
                if ($value ne $unit_name) {
                    push @links, get_link_closure($value, find_unit($value));
                }
            }
        }

if ($line =~ /^\s*Alias=(.+)$/i) {
            for my $value (split(/\s+/, $1)) {
                $value =~ s/^(["'])(.*)\g1$/$2/;
                if ($value ne $unit_name) {
                    push @links, { dest => $service_path, src => "/etc/systemd/$instance/$1" };
                }
            }
        }
    }
    close($fh);

return @links;
}

sub all_links_installed {
    my ($scriptname, $service_path) = @_;

my @links = get_link_closure($scriptname, $service_path);
    my @missing_links = grep { ! -l $_->{src} } @links;

return (@missing_links == 0);
}

sub no_link_installed {
    my ($scriptname, $service_path) = @_;

my @links = get_link_closure($scriptname, $service_path);
    my @existing_links = grep { -l $_->{src} } @links;

return (@existing_links == 0);
}

sub enable {
    my ($scriptname, $service_path) = @_;
    if ($has_systemctl) {
        # We use 'systemctl preset' on the initial installation only.
        # On upgrade, we manually add the missing symlinks only if the
        # service already has some links installed. Using 'systemctl
        # preset' allows administrators and downstreams to alter the
        # enable policy using systemd-native tools.
        my $create_links = 0;
        if (debian_installed($scriptname)) {
            $create_links = 1 unless no_link_installed($scriptname, $service_path);
        } else {
            debug "Using systemctl preset to enable $scriptname";
            system("/bin/systemctl",
                   $instance eq "user" ? "--global" : "--system",
                   "--preset-mode=enable-only",
                   "preset", $scriptname) == 0
                or error("systemctl preset failed on $scriptname: $!");
        }
        make_systemd_links($scriptname, $service_path, create_links => $create_links);
    } else {
        # We create all the symlinks ourselves
        make_systemd_links($scriptname, $service_path);
    }
}

sub make_systemd_links {
    my ($scriptname, $service_path, %opts) = @_;
    $opts{'create_links'} //= 1;

my $dsh_state = dsh_state_path($scriptname);

my @links = get_link_closure($scriptname, $service_path);
    for my $link (@links) {
        my $service_path = $link->{dest};
        my $service_link = $link->{src};

record_in_statefile($dsh_state, $service_link);

my $statefile = $service_link;
        $statefile =~ s,^/etc/systemd/$instance/,$enabled_state_dir/,;
        next if -e $statefile;

if ($opts{'create_links'} && ! -l $service_link) {
            make_path(dirname($service_link));
            symlink($service_path, $service_link) or
                error("unable to link $service_link to $service_path: $!");
            $changed_sth = 1;
        }

# Store the fact that we ran enable for this service_path,
        # so that we can skip enable the next time.
        # This allows us to call deb-systemd-helper unconditionally
        # and still only enable unit files on the initial installation
        # of a package.
        make_path(dirname($statefile));
        open(my $fh, '>>', $statefile);
        close($fh);
    }

}

# In contrary to make_systemd_links(), which only modifies the state file in an
# append-only fashion, update_state() can also remove entries from the state
# file.
#
# The distinction is important because update_state() should only be called
# when the unit file(s) are guaranteed to be on-disk, e.g. on package updates,
# but not on package removals.
sub update_state {
    my ($scriptname, $service_path) = @_;

my $dsh_state = dsh_state_path($scriptname);
    my @links = get_link_closure($scriptname, $service_path);

debug "Old state file contents: " .
        Data::Dumper::Dumper([ state_file_entries($dsh_state) ]);

make_path(dirname($dsh_state));
    my ($outfh, $tmpname) = tempfile('.stateXXXXX',
        DIR => dirname($dsh_state),
        SUFFIX => '.tmp',
        UNLINK => 0);
    chmod(0644, $tmpname);
    for my $link (@links) {
        print $outfh $link->{src} . "\n";
    }
    close($outfh);

debug "Renaming temp file $tmpname to state file $dsh_state";
    rename($tmpname, $dsh_state) or
        error("Unable to move $tmpname to $dsh_state");

debug "New state file contents: " .
        Data::Dumper::Dumper([ state_file_entries($dsh_state) ]);
}

sub was_enabled {
    my ($scriptname) = @_;

my @entries = state_file_entries(dsh_state_path($scriptname));
    debug "Contents: " . Data::Dumper::Dumper(\@entries);

for my $link (@entries) {
        if (! -l $link) {
            debug "Link $link is missing, considering $scriptname was-disabled.";
            return 0;
        }
    }

debug "All links present, considering $scriptname was-enabled.";
    return 1;
}

sub debian_installed {
    my ($scriptname) = @_;
    return -f dsh_state_path($scriptname);
}

sub remove_links {
    my ($service_path) = @_;

my $dsh_state = dsh_state_path($service_path);
    my @entries = state_file_entries($dsh_state);
    debug "Contents: " . Data::Dumper::Dumper(\@entries);

if (is_purge()) {
        unlink($dsh_state) if -e $dsh_state;
    }

# Also disable all the units which were enabled when this one was enabled.
    for my $link (@entries) {
        # Delete the corresponding state file:
        # • Always when purging
        # • If the user did not disable (= link still exists) the service.
        #   If we don’t do this, the link will be deleted a few lines down,
        #   but not re-created when re-installing the package.
        if (is_purge() || -l $link) {
            my $link_state = $link;
            $link_state =~ s,^/etc/systemd/$instance/,$enabled_state_dir/,;
            unlink($link_state);
        }

next unless -l $link;
        unlink($link) or
            print STDERR "$0: unable to remove '$link': $!\n";

$changed_sth = 1;
    }

# Read $service_path, recurse for all Also= units.
    # This might not work when $service_path was already deleted,
    # i.e. after apt-get remove. In this case we just return
    # silently in order to not confuse the user about whether
    # disabling actually worked or not — the case is handled by
    # dh_installsystemd generating an appropriate disable
    # command by parsing the service file at debhelper-time.
    open(my $fh, '<', $service_path) or return;
    while (my $line = <$fh>) {
        chomp($line);
        my $service_link;

if ($line =~ /^\s*Also=(.+)$/i) {
            remove_links(find_unit($1));
        }
    }
    close($fh);
}

# Recursively deletes a directory structure, if all (!) components are empty,
# e.g. to clean up after purging.
sub rmdir_if_empty {
    my ($dir) = @_;

debug "rmdir_if_empty $dir";

rmdir_if_empty($_) for (grep { -d } <$dir/*>);

if (!rmdir($dir)) {
        debug "rmdir($dir) failed ($!)";
    }
}

sub mask_service {
    my ($scriptname, $service_path) = @_;

my $mask_link = "/etc/systemd/$instance/" . basename($service_path);

if (-e $mask_link) {
        # If the link already exists, don’t do anything.
        return if -l $mask_link && readlink($mask_link) eq '/dev/null';

# If the file already exists, the user most likely copied the .service
        # file to /etc/ to change it in some way. In this case we don’t need to
        # mask the .service in the first place, since it will not be removed by
        # dpkg.
        debug "$mask_link already exists, not masking.";
        return;
    }

make_path(dirname($mask_link));
    # clean up after possible leftovers from Alias= to self (LP#1439793)
    unlink($mask_link);
    symlink('/dev/null', $mask_link) or
        error("unable to link $mask_link to /dev/null: $!");
    $changed_sth = 1;

my $statefile = $mask_link;
    $statefile =~ s,^/etc/systemd/$instance/,$masked_state_dir/,;

# Store the fact that we masked this service, so that we can unmask it on
    # installation time. We cannot unconditionally unmask because that would
    # interfere with the user’s decision to mask a service.
    make_path(dirname($statefile));
    open(my $fh, '>>', $statefile);
    close($fh);
}

sub unmask_service {
    my ($scriptname, $service_path) = @_;

my $mask_link = "/etc/systemd/$instance/" . basename($service_path);

# Not masked? Nothing to do.
    return unless -e $mask_link;

if (! -l $mask_link || readlink($mask_link) ne '/dev/null') {
        debug "Not unmasking $mask_link because it is not a link to /dev/null";
        return;
    }

my $statefile = $mask_link;
    $statefile =~ s,^/etc/systemd/$instance/,$masked_state_dir/,;

if (! -e $statefile) {
        debug "Not unmasking $mask_link because the state file $statefile does not exist";
        return;
    }

unlink($mask_link) or
        error("unable to remove $mask_link: $!");
    $changed_sth = 1;
    unlink($statefile);
}

my $result = GetOptions(
    "quiet" => \$quiet,
    "user" => sub { $instance = 'user'; },
    "system" => sub { $instance = 'system'; }, # default
);

if ($instance eq 'user') {
    debug "is user unit = yes";
    $enabled_state_dir = USER_INSTANCE_ENABLED_STATE_DIR;
    $masked_state_dir = USER_INSTANCE_MASKED_STATE_DIR;
}

my $action = shift;
if (!defined($action)) {
    # Called without arguments. Explain that this script should not be run interactively.
    print "$0 is a program which should be called by dpkg maintscripts only.\n";
    print "Please do not run it interactively, ever. Also see the manpage deb-systemd-helper(1).\n";
    exit 0;
}

if (!$ENV{DPKG_MAINTSCRIPT_PACKAGE}) {
    print STDERR "$0 was not called from dpkg. Exiting.\n";
    exit 1;
}

if ($action eq 'purge') {
    $ENV{_DEB_SYSTEMD_HELPER_PURGE} = 1;
    $action = 'disable';
}

debug "is purge = " . (is_purge() ? "yes" : "no");

my $rc = 0;
if ($action eq 'is-enabled' ||
    $action eq 'was-enabled' ||
    $action eq 'debian-installed') {
    $rc = 1;
}
for my $scriptname (@ARGV) {
    my $service_path = find_unit($scriptname);

debug "action = $action, scriptname = $scriptname, service_path = $service_path";

if ($action eq 'is-enabled') {
        my $enabled = all_links_installed($scriptname, $service_path);
        print STDERR ($enabled ? "enabled\n" : "disabled\n") unless $quiet;
        $rc = 0 if $enabled;
    }

# was-enabled is the same as is-enabled, but only considers links recorded
    # in the state file. This is useful after package upgrades, to determine
    # whether the unit file was enabled before upgrading, even if the unit file
    # has changed and is not entirely enabled currently (due to a new Alias=
    # line for example).
    #
    # If all machines were running systemd, this issue would not be present
    # because is-enabled would query systemd, which would not have picked up
    # the new unit file yet.
    if ($action eq 'was-enabled') {
        my $enabled = was_enabled($scriptname);
        print STDERR ($enabled ? "enabled\n" : "disabled\n") unless $quiet;
        $rc = 0 if $enabled;
    }

if ($action eq 'update-state') {
        update_state($scriptname, $service_path);
    }

if ($action eq 'debian-installed') {
        $rc = 0 if debian_installed($scriptname);
    }

if ($action eq 'reenable') {
        remove_links($service_path);
        make_systemd_links($scriptname, $service_path);
    }

if ($action eq 'disable') {
        remove_links($service_path);
        # Clean up the state dir if it’s empty, or at least clean up all empty
        # subdirectories. Necessary to cleanly pass a piuparts run.
        rmdir_if_empty(SYSTEM_INSTANCE_ENABLED_STATE_DIR);
        rmdir_if_empty(USER_INSTANCE_ENABLED_STATE_DIR);

# Same with directories below /etc/systemd, where we create symlinks.
        # If systemd is not installed (and no other package shipping service
        # files), this would make piuparts fail, too.
        rmdir_if_empty($_) for (grep { -d } </etc/systemd/system/*>);
        rmdir_if_empty($_) for (grep { -d } </etc/systemd/user/*>);
    }

if ($action eq 'enable') {
        enable($scriptname, $service_path);
    }

if ($action eq 'mask') {
        mask_service($scriptname, $service_path);
    }

if ($action eq 'unmask') {
        unmask_service($scriptname, $service_path);
        # Clean up the state dir if it’s empty, or at least clean up all empty
        # subdirectories. Necessary to cleanly pass a piuparts run.
        rmdir_if_empty('/var/lib/systemd/deb-systemd-helper-masked');
    }
}

# If we changed anything and this machine is running systemd, tell
# systemd to reload so that it will immediately pick up our
# changes.
if ($changed_sth && $instance eq 'system' && -d "/run/systemd/system") {
    system("systemctl", "daemon-reload");
}

exit $rc;

=head1 AUTHOR

Michael Stapelberg <stapelberg@debian.org>

=cut

${this.title}

Code Editor : deb-systemd-helper